Мій АмперМетр

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128 
#define SCREEN_HEIGHT 64 
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

const int currentSensorPin = A1;   // Пин датчика тока (ACS758)
const int buttonPin = 2;           // Пин кнопки калибровки
float zeroCurrentVoltage = 2.559;  // Напряжение при 0A (по умолчанию)
const float sensitivity = 0.040;   
float OpornV = 5.159;
#define SCALE_Y 15          
#define SCALE_HEIGHT 9     
#define SCALE_START 10      
#define SCALE_WIDTH 108     
#define MAX_CURRENT 5.0      
#define BATTERY_PIN A0       

unsigned long lastBatteryMeasureTime = 0;
const unsigned long batteryMeasureInterval = 30000; 
float batteryVoltage = 0.0;

void setup() {
  Serial.begin(9600);
  
  pinMode(buttonPin, INPUT_PULLUP); 
  digitalWrite(buttonPin, HIGH); 

  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("Ошибка дисплея"));
    for(;;);
  }

  display.clearDisplay();
  display.setTextSize(3);
  display.setTextColor(WHITE);
  display.setCursor(5, 5);
  display.println("Amper");
  display.setCursor(23, 30);
  display.println("Metr");

  display.display();
  digitalWrite(buttonPin, LOW); 
  delay(2000);
  digitalWrite(buttonPin, HIGH); 

  batteryVoltage = analogRead(BATTERY_PIN) * (OpornV / 1023.0);
  lastBatteryMeasureTime = millis();
}

void loop() {
  unsigned long currentTime = millis();

  if(digitalRead(buttonPin) == LOW) {
    delay(50);
    if(digitalRead(buttonPin) == LOW) {
      zeroCurrentVoltage = analogRead(currentSensorPin) * (OpornV / 1023.0);
      while(digitalRead(buttonPin) == LOW) delay(10);
      delay(200);
    }
  }

  float current = (analogRead(currentSensorPin) * (OpornV / 1023.0) - zeroCurrentVoltage) / sensitivity;

  if(currentTime - lastBatteryMeasureTime >= batteryMeasureInterval) {
    batteryVoltage = analogRead(BATTERY_PIN) * (OpornV / 1023.0);
    lastBatteryMeasureTime = currentTime;
  }

  display.clearDisplay();
  drawCurrentScale(current);
  
  display.setTextSize(3);
  display.setCursor(0, 30);
  if(current >= 0) {
    display.print(" "); 
  }
  display.print(current, 3);
  display.setTextSize(1);
  display.setCursor(122, 44);
  display.println("A");
  
  display.setTextSize(1);
  display.setCursor(80, 56);
  display.println("max 50A");
  
  display.setCursor(10, 56);
  display.print(batteryVoltage, 1);
  display.print("V");
  
  display.display();
  delay(250);
}

void drawCurrentScale(float current) {
  
  int centerX = SCALE_START + SCALE_WIDTH/2;
  
  display.drawLine(SCALE_START, SCALE_Y, SCALE_START + SCALE_WIDTH, SCALE_Y, WHITE);
 
  if(current > 0) {
    int pos = map(current * 100, 0, MAX_CURRENT * 100, centerX, SCALE_START + SCALE_WIDTH);
    display.fillRect(centerX + 1, SCALE_Y + 1, pos - centerX - 1, SCALE_HEIGHT - 2, WHITE);
  } else if(current < 0) {
    int pos = map(current * 100, 0, -MAX_CURRENT * 100, centerX, SCALE_START);
    display.fillRect(pos + 1, SCALE_Y + 1, centerX - pos - 1, SCALE_HEIGHT - 2, WHITE);
  }
  
  for(int i = -4; i <= 4; i += 2) {
    int x = map(i, -MAX_CURRENT, MAX_CURRENT, SCALE_START, SCALE_START + SCALE_WIDTH);
    display.drawLine(x, SCALE_Y, x, SCALE_Y + 5, WHITE);

    display.setTextSize(1);
    display.setCursor(x - (abs(i) < 10 ? 3 : 6), SCALE_Y - 10);
    display.print(i);
  }
  
  int pointerPos = map(constrain(current * 100, -MAX_CURRENT * 100, MAX_CURRENT * 100), 
                      -MAX_CURRENT * 100, MAX_CURRENT * 100, 
                      SCALE_START, SCALE_START + SCALE_WIDTH);

  display.fillRect(pointerPos - 1, SCALE_Y - 2, 3, SCALE_HEIGHT + 2, WHITE);
  display.fillTriangle(
    pointerPos, SCALE_Y - 2,
    pointerPos - 2, SCALE_Y - 1,
    pointerPos + 2, SCALE_Y - 1,
    WHITE);
}