Портативний міні-дебаггер I2C/SPI на Arduino Nano

SDA -> A4
SCL -> A5
MOSI -> D11
MISO -> D12
SCK -> D13
SS -> D10

#include <U8g2lib.h>
#include <Wire.h>
#include <SPI.h>

#define OLED_ADDRESS 0x3C
#define CS_PIN 10    // SS
#define MOSI_PIN 11  // MOSI
#define MISO_PIN 12  // MISO
#define SCK_PIN 13   // SCK

// Ініціалізація дисплея
U8G2_SSD1306_72X40_ER_F_HW_I2C u8g2(U8G2_R0);
bool showSPI = false;

void setup() {
    Wire.begin();
    Wire.setClock(100000); // 100kHz для стабільності
    
    // Налаштовуємо SPI піни
    pinMode(CS_PIN, OUTPUT);
    pinMode(MISO_PIN, INPUT_PULLUP);
    pinMode(MOSI_PIN, OUTPUT);
    pinMode(SCK_PIN, OUTPUT);
    
    digitalWrite(CS_PIN, HIGH);
    SPI.begin();
    
    u8g2.begin();
    u8g2.setContrast(255);
}

void scanI2C() {
    byte count = 0;
    byte devices[10];
    
    // Сканування шини
    for(byte address = 1; address < 127; address++) {
        if(address == OLED_ADDRESS) continue; // Пропускаємо адресу дисплея
        
        Wire.beginTransmission(address);
        byte error = Wire.endTransmission();
        
        if(error == 0 && count < 10) {
            devices[count] = address;
            count++;
        }
        delay(1);
    }
    
    // Оновлення дисплея
    u8g2.firstPage();
    do {
        u8g2.setFont(u8g2_font_7x13_tr);
        u8g2.drawStr(2, 9, "I2C:");
        
        u8g2.setFont(u8g2_font_9x15_tr);
        
        char buffer[12];
        for(byte i = 0; i < count && i < 2; i++) {
            sprintf(buffer, "0x%02X", devices[i]);
            u8g2.drawStr(5, 24 + (i * 15), buffer);
        }
        
        if(count == 0) {
            u8g2.drawStr(5, 25, "NONE");
        }
        
    } while(u8g2.nextPage());
}

void scanSPI() {
    // Робимо кілька замірів для надійності
    byte responses[5];
    for(byte i = 0; i < 5; i++) {
        digitalWrite(CS_PIN, LOW);
        delayMicroseconds(100);
        responses[i] = SPI.transfer(0xFF);
        delayMicroseconds(100);
        digitalWrite(CS_PIN, HIGH);
        delay(1);
    }
    
    // Перевіряємо, чи змінюються значення
    bool hasResponse = false;
    for(byte i = 1; i < 5; i++) {
        if(responses[i] != responses[0]) {
            hasResponse = true;
            break;
        }
    }
    
    u8g2.firstPage();
    do {
        u8g2.setFont(u8g2_font_7x13_tr);
        u8g2.drawStr(2, 9, "SPI:");
        
        u8g2.setFont(u8g2_font_9x15_tr);
        
        if(hasResponse) {
            u8g2.drawStr(5, 24, "ACTIVE");
            char buffer[12];
            sprintf(buffer, "0x%02X", responses[0]);
            u8g2.drawStr(5, 39, buffer);
        } else {
            u8g2.drawStr(5, 24, "NONE");
        }
        
    } while(u8g2.nextPage());
}

void loop() {
    showSPI = !showSPI;
    
    if(showSPI) {
        scanSPI();
    } else {
        scanI2C();
    }
    
    delay(3000); // Перемикаємо режим кожні 3 секунди
}