Давай измерим "его"!

#include 
#include 
#include 
#include 

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET -1
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

#define BTN_SCAN D5
#define MAX_DISPLAY_NETWORKS 5
#define MAX_NETWORKS 50

int totalNetworks = 0;
String networks[MAX_NETWORKS];
int rssiValues[MAX_NETWORKS];

void setup() {
  Serial.begin(115200);
  
  Wire.begin(D2, D1);
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println("OLED error!");
    while(1);
  }
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(WHITE);
  
  pinMode(BTN_SCAN, INPUT_PULLUP);

  display.setCursor(0, 0);
  display.println("Starting in 3 sec...");
  display.display();
  delay(3000);
  scanNetworks();
}

void loop() {
  if (digitalRead(BTN_SCAN) == LOW) {
    delay(200);
    scanNetworks();
    while(digitalRead(BTN_SCAN) == LOW); // Ждём отпускания
  }
}

int rssiToPercent(int rssi) {
  if (rssi >= -30) return 100;
  if (rssi <= -100) return 0;
  return 2 * (rssi + 100);
}

// Функция для сортировки сетей по уровню сигнала
void sortNetworksByRSSI(String networkList[], int rssiList[], int size) {
  for (int i = 0; i < size - 1; i++) {
    for (int j = 0; j < size - i - 1; j++) {
      if (rssiList[j] < rssiList[j + 1]) {
        // Меняем местами RSSI
        int tempRssi = rssiList[j];
        rssiList[j] = rssiList[j + 1];
        rssiList[j + 1] = tempRssi;
        
        // Меняем местами соответствующие строки сетей
        String tempNetwork = networkList[j];
        networkList[j] = networkList[j + 1];
        networkList[j + 1] = tempNetwork;
      }
    }
  }
}

void scanNetworks() {
  display.clearDisplay();
  display.setCursor(0, 0);
  display.println("Scan...");
  display.display();

  int n = WiFi.scanNetworks(false, true);
  totalNetworks = min(n, MAX_NETWORKS);

  if (n == 0) {
    networks[0] = "No net!";
    rssiValues[0] = 0;
    totalNetworks = 1;
  } else {
    for (int i = 0; i < totalNetworks; i++) {
      String ssid = (WiFi.SSID(i).length() == 0 ? "[HIDDEN]" : WiFi.SSID(i));
      rssiValues[i] = WiFi.RSSI(i);
      int percent = rssiToPercent(rssiValues[i]);
      networks[i] = ssid + " " + String(percent) + "%";
    }
    
    // Сортируем сети по уровню сигнала
    sortNetworksByRSSI(networks, rssiValues, totalNetworks);
  }
  
  displayResults();
}

void displayResults() {
  display.clearDisplay();
  display.setCursor(0, 0);
  
  for (int i = 0; i < min(totalNetworks, MAX_DISPLAY_NETWORKS); i++) {
    display.print(String(i+1) + ". ");
    display.println(networks[i]);
  }
  
  display.display();
}